Hi folks,
We are having an issue where we are seeing a webcam subscriber with streamCount = 2 (and indeed, displaying multiple camera streams) even though its publisherIDs.length = 1.
This seems to be occurring when we try to change the publisherIDs array of a webcam subscriber while the publishing user to which the webcam subscriber's publisherIDs are currently set is temporarily out of the room (for example, if they have refreshed their browser). Once this initial publisher re-enters the room and resumes publishing his camera stream, our webcam subscriber picks up the stream and displays it alongside the new stream.
Examining the the source code provided here (http://forums.adobe.com/message/3718199#3718199), this seems to be a consequence of the way that webcam subscribers handle new STREAM_RECEIVE events.
Please have a look at the following excerpt from WebcamSubscriber.as (relevant code in bold for emphasis):
It would appear that _publisherIDs and _publisherIDTable are getting out of sync. The _publisherIDTable object is only removing stream publisher IDs from itself if the stream still exists in the room. When STREAM_RECEIVE events are fired, the webcam subscriber checks against _publisherIDTable, rather than _publisherIDs, to determine whether or not to play the stream. As the _publisherIDTable is retaining certain ID's that do not exist in _publisherIDs, we are seeing this issue of multiple streams displayed on a webcam subscriber even when we have set the publisherIDs array for that webcam subscriber to a single element array.
public function set publisherIDs(p_publishers:Array):void
{
var tempNewPublisherTable:Object = new Object();
var i:int = 0 ;
// comparing the old list to the new list ...
if ( _streamManager == null ) {
_publisherIDs = p_publishers;
var l:int = _publisherIDs.length;
for (i=0; i<l; i++) {
_publisherIDTable[_publisherIDs[i]] = true;
}
}else {
for ( i= 0 ; i < p_publishers.length ; i++ ) {
if ( _publisherIDTable[p_publishers[i]] == null ) {
_publisherIDTable[p_publishers[i]] = true ;
if ( _streamManager.getStreamDescriptor(StreamManager.CAMERA_STREAM,p_publishers[i]) != null ){
// we need to play only those that exists...
playStream(p_publishers[i]);
}
}
tempNewPublisherTable[p_publishers[i]] = true ;
}
for ( var id:String in _streamDescriptorTable ) {
var remainingPublisher:String = (_streamDescriptorTable[id] as StreamDescriptor).streamPublisherID ;
if ( tempNewPublisherTable[remainingPublisher] == null ) {
deleteStream(_streamDescriptorTable[id]);
delete _publisherIDTable[remainingPublisher] ;
}
}
if ( _publisherIDs.length != p_publishers.length ) {
dispatchEvent(new Event("numberOfStreamsChange"));
}
_publisherIDs = p_publishers ;
displayInvalidator.invalidate();
}
}
protected function shouldDisplayStream(p_desc:StreamDescriptor):Boolean
{
return (_publisherIDs.length==0 || _publisherIDTable[p_desc.streamPublisherID]==true);
}
protected function onStreamReceive (p_evt:StreamEvent):void
{
var streamDescriptor:StreamDescriptor;
streamDescriptor = p_evt.streamDescriptor ;
if (streamDescriptor==null || (streamDescriptor.groupName && streamDescriptor.groupName != _groupName) ) {
return ;
}
if (!shouldDisplayStream(streamDescriptor)) {
// Don't display the stream if it is not in the list.
return;
}
if (streamDescriptor.finishPublishing && streamDescriptor.type == StreamManager.CAMERA_STREAM ){
if ( streamDescriptor.nativeWidth!=0 && streamDescriptor.nativeHeight!=0){
playStream(streamDescriptor.streamPublisherID);
}
dispatchEvent(new Event("numberOfStreamsChange"));
dispatchEvent(p_evt);
displayInvalidator.invalidate();
}
}
Thanks for your help,
Davis
)
