Matt,,
Please add the pods after the kockingqueue uesr is accepted. That should fix your issue.
I have attached the working version of your app.
<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
xmlns:s="library://ns.adobe.com/flex/spark"
xmlns:mx="library://ns.adobe.com/flex/mx"
xmlns:fp="com.devaldi.controls.flexpaper.*"
xmlns:rtc="http://ns.adobe.com/rtc"
xmlns:coreUI="http://ns.adobe.com/coreUI"
xmlns:components="components.*"
xmlns:session="com.adobe.rtc.session.*"
xmlns:authentication="com.adobe.rtc.authentication.*"
xmlns:collaboration="com.adobe.rtc.collaboration.*"
xmlns:pods="com.adobe.rtc.pods.*"
width="960" height="600" minWidth="960" minHeight="600" maxWidth="900"
maxHeight="600" backgroundColor="#eeeeee">
<fx:Declarations>
<!-- Place non-visual elements (e.g., services, value objects) here -->
</fx:Declarations>
<fx:Script>
<![CDATA[
import com.adobe.rtc.collaboration.WebcamSubscriber;
import com.adobe.rtc.events.AuthenticationEvent;
import com.adobe.rtc.events.SessionEvent;
import com.adobe.rtc.events.StreamEvent;
import com.adobe.rtc.events.UserEvent;
import com.adobe.rtc.events.UserQueueEvent;
import com.adobe.rtc.messaging.UserRoles;
import com.adobe.rtc.pods.Note;
import com.adobe.rtc.sharedManagers.RoomManager;
import com.adobe.rtc.sharedManagers.StreamManager;
import com.adobe.rtc.sharedManagers.UserManager;
import com.adobe.rtc.sharedManagers.constants.UserStatuses;
import com.adobe.rtc.sharedModel.UserQueue;
import com.adobe.rtc.sharedModel.userQueueClasses.UserQueueItem;
import flash.media.Microphone;
import mx.collections.ArrayCollection;
import mx.controls.Alert;
import mx.core.FlexGlobals;
import mx.events.FlexEvent;
import mx.managers.PopUpManager;
import mx.utils.ObjectUtil;
import spark.components.TitleWindow;
import spark.events.TitleWindowBoundsEvent;
private var _userManager:UserManager;
private var _streamManager:StreamManager;
[Bindable]
private var localVol:Number = 70;
private function onCreationComplete():void
{
// Require that guests must knock.Note that this line changes the setting of your room so that in future anyone guest coming in
// has to knock. You can change this setting again either from code by making roomManager.guestsHaveToKnock as false or from the DevConsole's manage tab
cSession.roomManager.guestsHaveToKnock = true ;
// For owners that arrive late, the pending queue is populated with waiting users.
if ( cSession.userManager.myUserRole == UserRoles.OWNER ) {
var pendingArray:Array = new Array();
var queue:Array = cSession.roomManager.knockingQueue.pendingQueue ;
for ( var i:int = 0 ; i < queue.length ; i++ ) {
var item:UserQueueItem = queue[i] as UserQueueItem ;
pendingArray.push({label:item.descriptor.displayName,descriptor:item.descriptor});
}
knockingList.dataProvider = pendingArray ;
cSession.roomManager.knockingQueue.addEventListener(UserQueueEvent.ITEM_UPDATE,onKnockingQueueUpdate);
cSession.roomManager.knockingQueue.roleForManaging = UserRoles.PUBLISHER;
addPods();
}else {
//Else, remove all UI from seeing.
knockingUI.removeAllChildren() ;
}
if ( cSession.userManager.myUserRole == UserRoles.LOBBY ) {
cSession.roomManager.knockingQueue.addEventListener(UserQueueEvent.ACCEPT,onMyAccept);
cSession.roomManager.knockingQueue.addEventListener(UserQueueEvent.DENY,onMyDeny);
}
}
private function addPods():void
{
var notePod:Note = new Note();
notePod.width = notePod.height = 200;
notePod.connectSession = cSession;
notePod.sharedID = "notePod";
notePod.subscribe();
//noteTab.addChild(notePod);
noteTab.addElement(notePod);
}
// When the queue changes, update the pending, knocking, and denied list
private function onKnockingQueueUpdate(p_evt:UserQueueEvent):void
{
var pendingArray:Array = new Array();
// For the pending list you can directly use the pendingQueue property in UserQueue. For details,
// see the onCreationComplete documentation in the LCCS API Reference.
var acceptedArray:Array = new Array();
var deniedArray:Array = new Array();
var queue:Array = cSession.roomManager.knockingQueue.queue ;
for ( var i:int = 0 ; i < queue.length ; i++ ) {
var item:UserQueueItem = queue[i] as UserQueueItem ;
if ( item.status == UserQueueItem.STATUS_PENDING ) {
pendingArray.push({label:item.descriptor.displayName,descriptor:item.descriptor});
}
if ( item.status == UserQueueItem.STATUS_ACCEPTED ) {
acceptedArray.push({label:item.descriptor.displayName,descriptor:item.descriptor});
}
if ( item.status == UserQueueItem.STATUS_DENIED ) {
deniedArray.push({label:item.descriptor.displayName,descriptor:item.descriptor});
}
}
knockingList.dataProvider = pendingArray ;
acceptedList.dataProvider = acceptedArray ;
deniedList.dataProvider = deniedArray ;
}
// Accept the knocker.
private function onAcceptClick(p_evt:MouseEvent):void
{
if ( cSession.userManager.myUserRole == UserRoles.OWNER ) {
cSession.roomManager.knockingQueue.acceptUser(knockingList.selectedItem.descriptor.userID);
}
}
// Deny the knocker.
private function onDenyClick(p_evt:MouseEvent):void
{
if ( cSession.userManager.myUserRole == UserRoles.OWNER )
cSession.roomManager.knockingQueue.denyUser(knockingList.selectedItem.descriptor.userID);
}
// Update the user's user interface when they are accepted by letting them see the chat window.
private function onMyAccept(p_evt:UserQueueEvent):void
{
knockingUI.addChild(compContainer);
addPods();
compContainer.percentWidth = 100 ;
compContainer.percentHeight = 80 ;
}
// Show denied users a blank screen.
private function onMyDeny(p_evt:UserQueueEvent):void
{
knockingUI.removeAllChildren();
}
// This is the section which handles a video subscriber
private function onSyncChange():void{
if (cSession.isSynchronized){
cSession.roomManager.autoPromote = true ;
_userManager = cSession.userManager;
_streamManager = cSession.streamManager;
_streamManager.addEventListener(StreamEvent.STREAM_DELETE, onStreamLeft);
_streamManager.addEventListener(StreamEvent.STREAM_RECEIVE, onStreamReceive);
trace("onSyncChange");
displayExistingStreams()
}
else {
// to do
}
}
private function onStreamReceive(p_evt:StreamEvent):void
{
trace("on Stream receive : "+p_evt.streamDescriptor.streamPublisherID);
if (p_evt.streamDescriptor.streamPublisherID!=_userManager.myUserID) {
setUpSubscriber( p_evt.streamDescriptor.streamPublisherID);
}
}
private function onStreamLeft(evt:StreamEvent):void{
if (evt.streamDescriptor.streamPublisherID != _userManager.myUserID){
// to do
}
}
private function setUpSubscriber(p_publisherID:String):void
{
trace("subscribing to : "+p_publisherID);
webcamSubExt.connectSession = cSession ;
webcamSubExt.subscribe();
webcamSubExt.publisherIDs = [p_publisherID];
}
// run this function once, on connectSession.synchronizationChange (once the room is ready)
// sets up all streams that were in the room before you showed up
private function displayExistingStreams():void
{
// loop over the whole set of camera streams
var publishers:Object = _streamManager.getStreamsOfType(StreamManager.CAMERA_STREAM);
trace("all the "+publishers.length+" publishers : "+publishers);
var found:Boolean = false;
for (var publisherID:String in publishers) {
trace("found a camera : "+publisherID);
if (publisherID!=_userManager.myUserID) {
trace("it's not me");
setUpSubscriber(publisherID);
found=true;
}
}
}
// End of code which handles a video subscriber
/*****
* Handler for the stop and start buttons.
*******/
private function onPublishClick(p_evt:MouseEvent):void
{
if ( p_evt.currentTarget.label == "Publish" )
{
webcamPub.publish();
audioPub.publish();
p_evt.currentTarget.label = "Stop" ;
}else if (p_evt.currentTarget.label == "Stop" )
{
webcamPub.stop();
audioPub.stop();
p_evt.currentTarget.label = "Publish" ;
}
}
private function onGainChange(event:Event):void
{
audioSub.setLocalVolume(gainSlider.value/100);
}
]]>
</fx:Script>
<session:ConnectSessionContainer id="cSession" width="100%" height="80%"
creationComplete="onCreationComplete()"
roomURL="https://collaboration.adobelivecycle.com/ag/as/"
synchronizationChange="onSyncChange()">
<session:authenticator>
<authentication:AdobeHSAuthenticator id="auth" protocol="rtmfp"
userName="aponn"/>
</session:authenticator>
<mx:VBox id="knockingUI" width="100%" height="100%">
<s:BorderContainer width="960" height="600" backgroundColor="#eeeeee" borderWeight="3"
horizontalCenter="0" verticalCenter="0" id="compContainer">
<s:HGroup id="clientUI" left="10" right="10" top="10" bottom="10">
<collaboration:WebcamPublisher id="webcamPub" width="0" height="0" fps="10"
quality="70" />
<s:VGroup width="240" height="100%" gap="0" paddingRight="10">
<s:VGroup width="240" height="280">
<collaboration:WebcamSubscriber id="webcamSubExt" width="240" height="240"
displayUserBars="false"/>
<s:VGroup width="100%" horizontalAlign="center">
<s:HSlider id="gainSlider" change="onGainChange(event)"
liveDragging="true" maximum="100" minimum="0"
value="{localVol}"/>
</s:VGroup>
<collaboration:AudioPublisher id="audioPub" width="0" height="0" gain="60"
useEchoSuppression="true"/>
<collaboration:AudioSubscriber id="audioSub" width="0" height="0"/>
</s:VGroup>
<s:VGroup width="240" height="100%" horizontalAlign="left">
<s:HGroup width="240">
<collaboration:WebcamSubscriber width="120" height="120"
displayUserBars="false"
publisherIDs="{[cSession.userManager.myUserID]}"
webcamPublisher="{webcamPub}"/>
<s:VGroup width="100%" height="100%">
<s:HGroup width="110">
<s:ToggleButton id="videoStartBtn" label="Publish"
click="onPublishClick(event)"/>
</s:HGroup>
</s:VGroup>
</s:HGroup>
</s:VGroup>
</s:VGroup>
<mx:Spacer width="10"/>
<mx:TabNavigator id="podTabs" width="660" height="100%">
<s:NavigatorContent id="noteTab" width="100%" height="540" label="Notes">
</s:NavigatorContent>
<s:NavigatorContent width="100%" height="540" label="Whiteboard" id="wbTab">
</s:NavigatorContent>
</mx:TabNavigator>
</s:HGroup>
</s:BorderContainer>
<mx:HBox width="100%" height="20%" horizontalGap="15">
<mx:VBox>
<mx:Label text="Pending User List"/>
<mx:List id="knockingList" width="100%" height="200"/>
<mx:HBox>
<mx:Button label="accept" click="onAcceptClick(event)"
enabled="{knockingList.selectedItem}"/>
<mx:Button label="deny" click="onDenyClick(event)"
enabled="{knockingList.selectedItem}"/>
</mx:HBox>
</mx:VBox>
<mx:VBox>
<mx:Label text="Accepted User List"/>
<mx:List id="acceptedList" width="100%" height="200"/>
</mx:VBox>
<mx:VBox>
<mx:Label text="Denied User List"/>
<mx:List id="deniedList" width="100%" height="200"/>
</mx:VBox>
</mx:HBox>
</mx:VBox>
</session:ConnectSessionContainer>
</s:Application>
Thanks
Arun
